Myujth

I am trying to group two object into one list to be iterated in one 'for each' loop. Is it even possible in VBA/VBscript?

For example I would like to delete all files and folders from a specific location basing on last mod. date and I don't want to create two loops.

Set oFolder = fso.GetFolder(FolderPath)
Set oFileList = oFolder.Files
Set oFolderList = oFolder.SubFolders
Set oFullList = oFileList + oFolderList (???)

For Each oFile In oFullList 
 lastModDate = oFile.DateLastModified
 If (lastModDate < PurgeDate) Then
 oFile.Delete True
 End If
Next

What you're asking is not possible with FileSystemObject methods alone. Even if you created a single array or ArrayList from the elements of oFolder.Files and oFolder.SubFolders you'd need two individual loops to do so.

You could use the Shell.Application object for enumerating folder content, but the resulting objects don't have a delete method, so you'd still need FileSystemObject objects and methods for deleting the files/folders:

path = "C:somefolder"

Set app = CreateObject("Shell.Application")
Set fso = CreateObject("Scripting.FileSystemObject")

For Each it In app.NameSpace(path).Items
 If it.IsFolder Then
 fso.GetFolder(it.Path).Delete
 Else
 fso.GetFile(it.Path).Delete
 End If
Next

However, I fail to see a significant advantage of this approach over using just FileSystemObject methods and looping twice. If you're concerned about duplicating code just wrap the loop in a procedure and call that procedure for both subfolders and files.

path = "C:somefolder"

Sub DeleteItems(list)
 For Each it In list
 it.Delete
 Next
End Sub

Set fso = CreateObject("Scripting.FileSystemObject")
Set oFolder = fso.GetFolder(path)

DeleteItems oFolder.Files
DeleteItems oFolder.SubFolders